Директивы компиляции по условию

Макродирективы

       С помощью макросредств ассемблера можно не только частично изменять входящие в макроопределение строки, но и модифицировать сам набор этих строк и даже порядок их следования. Сделать это можно с помощью набора макродиректив (далее — просто директив). Их можно разделить на две группы.

       1.Директивы повторения WHILE, REPT, IRP и IRPC предназначены для создания макросов, содержащих несколько идущих подряд одинаковых последовательностей строк. При этом возможна частичная модификация этих строк.

       2. Директивы управления процессом генерации макрорасширений EXITM и GOTO предназначены для управления процессом формирования макрорасширения из набора строк соответствующего макроопределения. С помощью этих директив можно как исключать отдельные строки из макрорасширения, так и вовсе прекращать процесс генерации. Директивы EXITM и GOTO обычно используются вместе с условными директивами компиляции, поэтому они будут рассмотрены вместе с ними.

Директивы WHILE и REPT

       Директивы WHILE и REPT применяются для повторения определенное количество раз некоторой последовательности строк. Эти директивы имеют следующий синтаксис:

WHILE константное_выражение

последовательность строк

ENDM

REPT константное_выражение

последовательность строк

ENDM

       Обратите внимание на то, что последовательность повторяемых строк в обеих директивах ограничена директивой ENDM.

       При использовании директивы WHILE макрогенератор транслятора будет повторять последовательность строк до тех пор, пока значение константное_выражение не станет равным нулю. Это значение вычисляется каждый раз перед очередной итерацией цикла повторения (то есть значение константное_выражение в процессе макрогенерации должно подвергаться изменению внутри последовательности строк).

       Директива REPT, подобно директиве WHILE, повторяет последовательность строк столько раз, сколько это определено значением константное_выражение. Отличие этой директивы от WHILE состоит в том, что она автоматически уменьшает на единицу значение константное_выражение после каждой итерации.

       Пример. В нем демонстрируется применение директив WHILE и REPT для резервирования области памяти в сегменте данных. Имя идентификатора и длина области задаются в качестве параметров соответствующих макросов def_sto_l и def_sto_2. Заметьте, что счетчик повторений в директиве REPT уменьшается автоматически после каждой итерации цикла.

       Использование директив повторения

def_sto_l macro id_table, ln:=<5>

;макрос резервирования памяти длиной ten

; Используется WHILE

id_table label byte

len=ln

       while len

                   db 0

                   len=len-l

       endm

endm

def_sto_2 macro id_table, len

;макрос резервирования памяти длиной len

;Используется REPT

id_table label byte

       rept len

                   db 0

       endm

endm

data segment para public 'data'

def_sto_l tab_l, 10

def_sto_2 tab_2, 10

data ends

init_ds macro

;Макрос настройки ds на сегмент данных

mov ax, data

mov ds. ax

endm

exit macro

;макрос конца программы

mov ax, 4c00h

int 21h

endm

code segment para public ‘code’

assume cs:code, ds:data

main proc

init_ds

exit

main endp

code ends

end main

       Таким образом, директивы REPT и WHILE удобно применять для «размножения » в тексте программы последовательности одинаковых строк без внесения в эти строки каких-либо изменений на этапе трансляции.

Директива IRP

       Директива IRP имеет следующий синтаксис:

IRP формальный_аргумент, <строка_символов_1,…, строка_символов_n>

последовательность строк

ENDM

       Действие данной директивы заключается в том, что она повторяет последовательность строк п раз, то есть столько раз, сколько строк символов заключено в угловые скобки во втором операнде директивы IRP. Повторение последовательности строк сопровождается заменой в этих строках формального аргумента очерёдной строкой символов из второго операнда. Так, при первой генерации последовательности строк формальный аргумент в них заменяется первой строкой символов (то есть аргументом строка_символов_1). Если есть вторая строка символов (строка_символов_2), это приводит к генерации второй копии последовательности строк, в которой формальный аргумент заменяется второй строкой символов. Эти действия продолжаются до последней строки символов (строка_символов_n) включительно.

       К примеру, рассмотрим результат определения в программе такой конструкции:

irp ini, <1, 2, 3, 4, 5>

db ini

endm

Макрогенератором будет сгенерировано следующее макрорасширение:

db 1

db 2

db 3

db 4

db 5

Директива IRPC

       Директива IRPC имеет следующий синтаксис:

IRPC формальный_аргумент, строка_символов

последовательность строк

ENDM

       Действие данной директивы подобно действию директивы IRP, но отличается тем, что она на каждой очередной итерации заменяет формальный аргумент очередным символом из строки символов. Понятно, что количество повторений последовательности строк будет определяться количеством символов в строке символов. К примеру,

irpc rg. abcd

push rg&x

endm

В процессе макрогенерации эта директива развернется в следующую последовательность строк:

push ax

push bx

push ex

push dx

       Если строка символов, задаваемая в директиве IRP, содержит спецсимволы вроде точек и запятых, то она должна быть заключена в угловые скобки:<ab, , cd>.

Директивы условной компиляции

       Последний тип макросредств — директивы условной компиляции. Существует два вида этих директив:

       1. директивы компиляции по условию позволяют проанализировать определенные условия в ходе генерации макрорасширения и при необходимости изменить этот процесс;

       2. директивы генерации ошибок по условию контролируют ход генерации макро-расширения с целью генерации или обнаружения определенных ситуаций, которые могут интерпретироваться как ошибочные.

       С этими директивами применяются упомянутые ранее директивы управления процессом генерации макрорасширений EXITM и GOTO.

       Директива EXITM не имеет операндов, она немедленно прекращает процесс генерации макрорасширения, как только встречается в макроопределении.

       Директива GOTO имя_метки переводит процесс генерации макроопределения в другое место, прекращая тем самым последовательное разворачивание строк макроопределения. Метка, на которую передается управление, имеет специальный формат:

       :имя_метки

Директивы компиляции по условию

       Директивы компиляции по условию предназначены для выборочной трансляции фрагментов программного кода. Это означает, что в макрорасширение включаются не все строки макроопределения, а только те, которые удовлетворяют определенным условиям. Какие конкретно условия должны быть проверены, определяется типом условной директивы. Всего имеются 10 типов условных директив компиляции. Их логично попарно объединить в четыре группы:

       1. IF и IFE — условная трансляция по результату вычисления логического выражения;

       2. IFDEF и IFNDEF — условная трансляция по факту определения символического имени;

       3. IFB и IFNB – условная трансляция по факту определения фактического аргумента при вызове макрокоманды;

       4. IFIDN, IFIDNI, IFDIF и IFDIFI — условная трансляция по результату сравнения строк символов.

       Условные директивы компиляции имеют общий синтаксис и применяются в составе следующей синтаксической конструкции:

IFxxx логическое_выражение_или_аргументы

фрагмент_программы_1

ELSE

фрагмент_программы_2

ENDIF

       Заключение некоторых фрагментов текста программы (фрагмент_программы_1 и фрагмент_программы_2) между директивами IFxxx, ELSE и ENDIF приводит к их выборочному включению в объектный модуль. Какой именно из этих фрагментов будет включен в объектный модуль, зависит от конкретного типа условной директивы, задаваемого значением ххх, и значения условия, определяемого операндом (операндами) условной директивы логическое_выражение_или_аргумент(ы).

Директивы IF и IFE

       Синтаксис директив IF и IFE следующий:

       IF(E)логическое_выражение

       фрагмент_программы_1

                   ELSE

       фрагмент_программы_2

       ENDIF

       Обработка этих директив макроассемблером заключается в вычислении логического выражения и включении в объектный модуль первого (фрагмент_программы_1) или второго (фрагмент_программы_2) фрагмента программы в зависимости от того, в какой директиве (IF или IFE)это выражение встретилось.

       1.Если в директиве IF логическое выражение истинно, то в объектный модуль помещается первый фрагмент программы. Если логическое выражение ложно, то при наличии директивы ELSE в объектный код помещается второй фрагмент программы. Если же директивы ELSE нет, то вся часть программы между директивами IF и ENDIF игнорируется, и в объектный модуль ничего не включается. Ложным оно будет считаться, если его значение равно нулю, а истинным — при любом значении, отличном от нуля.

       2. Директива IFE аналогично директиве IF анализирует значение логического выражения. Но теперь для включения первого фрагмента программы в объектный модуль требуется, чтобы логическое выражение было ложным.

       Директивы IF и IFE очень удобно использовать для изменения текста программы в зависимости от некоторых условий. К примеру, составим макрос для определения в программе области памяти длиной не более 50 и не менее 10 байт.

;Использование условных директив IF и IFE

masm

model small

stack 256

def_tab_50 macro len

if len GE 50

       GOTO exit

Endif

if len LT 10

:exit

EXITM

endif

rept len

       db 0

endm

endm

.data

def_tab_50 15

def_tab_50 5

.code

main:

       mov ax, @data

       mov ds, ax

exit:

       mov ax, 4c00h

       int 21h

end main

       Условные директивы действуют только на шаге трансляции, и поэтому результат их работы можно увидеть лишь после макрогенерации, то есть в листинге программы.

       Другой интересный и полезный вариант применения директив IF и IFE — отладочная печать. Суть здесь в том, что в процессе отладки программы почти всегда возникает необходимость динамически отслеживать состояние определенных программно-аппаратных объектов, в качестве которых могут выступать переменные, регистры процессора и т. п. После этапа отладки отпадает необходимость в таких диагностических сообщениях. Для их устранения приходится корректировать исходный текст программы, после чего подвергать ее повторной трансляции. Но есть более изящный выход. Можно определить в программе некоторую переменную, к примеру debug, и использовать ее совместно с условными директивами IF или IFE:

debug equ i

. code

…

if debug

;любые команды и директивы ассемблера

;(вывод на печать или монитор)

endif

       На время отладки и тестирования программы вы можете заключить отдельные участки кода в своеобразные операторные скобки в виде директив IF и ENDIF, реагирующие на значение логической переменной debug. При значении debug =0 транслятор полностью проигнорирует текст внутри этих условных операторных скобок;при debug =1, наоборот, будут выполнены все действия, описанные внутри них.

Директивы IFDEF и IFNDEF

       Синтаксис директив IFDEF и IFNDEF следующий:

IF(N)DEF символическое_имя

фрагмент_программы_1

ELSE

фрагмент_программы_2

ENDIF

       Данные директивы позволяют управлять трансляцией фрагментов программы в зависимости от того, определено или нет в программе некоторое символическое имя.

       1. Директива IFDEF проверяет, описано или нет в программе символическое имя, и если это так, то в объектный модуль помещается первый фрагмент программы (фрагмент_программы_1). В противном случае при наличии директивы ELSE в объектный код помещается второй фрагмент программы (фрагмент_программы_2). Если же директивы ELSE нет (и символическое имя в программе не описано), то вся часть программы между директивами IF и ENDIF игнорируется и в объектный модуль не включается.

       2. Действие IFNDEF обратно действию IFDEF. Если символического имени в программе нет, то транслируется первый фрагмент программы. Если оно присутствует, то при наличии ELSE транслируется второй фрагмент программы. Если ELSE отсутствует, а символическое имя в программе определено, то часть программы, заключенная между IFNDEF и ENDIF, игнорируется.

       В качестве примера рассмотрим ситуацию, когда в объектный модуль программы должен быть включен один из трех фрагментов кода в зависимости от значения некоторого идентификатора switch:

       – если switch =0, то сгенерировать фрагмент для вычисления выражения у=х*2**n;

       – если switch =1, то сгенерировать фрагмент для вычисления выражения у =х/2**n;

       – если идентификатор switch не определен, то ничего не генерировать.

       Соответствующий фрагмент исходной программы может выглядеть так:

ifndef sw ;если sw не определено, то выйти из макроса

EXITM

else ;иначе на вычисление

mov cl, n

       ife sw

                   sal x, cl ;умножение на степень 2 сдвигом влево

       else

                   sar x, cl ;деление на степень 2 сдвигом вправо

       endif

endif

       Как видим, эти директивы логически связаны с директивами IF и IFE, то есть их

можно применять в тех же самых случаях, что и последние.

Директивы IFB и IFNB

       Синтаксис директив IFB и IFNB следующий:

       IF(N)B аргумент

                   фрагмент_программы_1

       ELSE

                   фрагмент_программы_2

       ENDIF

       Данные директивы используются для проверки фактических параметров, передаваемых в макрос. При вызове макрокоманды они анализируют значение аргумента и в зависимости от того, равно оно пробелу или нет, транслируется либо первый фрагмент программы (фрагмент_программы_1), либо второй (фрагмент_программы_2). Какой именно фрагмент будет выбран, зависит от кода директивы.

       1. Директива IFB проверяет равенство аргумента пробелу. В качестве аргумента могут выступать имя или число. Если его значение равно пробелу (то есть фактический аргумент при вызове макрокоманды не был задан), то транслируется и помещается в объектный модуль первый фрагмент программы. В противном случае при наличии директивы ELSE в объектный код помещается второй фрагмент программы. Если же директивы ELSE нет, то при равенстве аргумента пробелу вся часть программы между директивами IFB и ENDIF игнорируется и в объектный модуль не включается.

       2. Действие IFNB обратно действию IFB. Если значение аргумента в программе не равно пробелу, то транслируется первый фрагмент программы. В противном случае при наличии директивы ELSE в объектный код помещается второй фрагмент программы. Если же директивы ELSE нет, то вся часть программы (при неравенстве аргумента пробелу)между директивами IFNB и ENDIF игнорируется и в объектный модуль не включается.

       Типичным примером применения этих директив являются строки в макроопределении, проверяющие, указывается ли фактический аргумент при вызове соответствующей макрокоманды:

show macro reg

ifb <reg>

display "не задан регистр"

exitm

endif

endm

       Если теперь в сегменте кода вызвать макрос SHOW без аргументов, то будет выведено сообщение о том, что не задан регистр, и генерация макрорасширения прекратится директивой EXITM.